Init

2026-06-15 22:41:52 +03:00 · 2025-05-15 21:11:30 +03:00
commit b6cee5e832
43 changed files with 2652 additions and 0 deletions
@@ -0,0 +1,59 @@
+{ inputs, ... }@flakeContext:
+let
+  homeModule =
+    {
+      config,
+      lib,
+      pkgs,
+      ...
+    }:
+    {
+      imports = [ inputs.self.homeModules.default ];
+      xdg = {
+        enable = true;
+        autostart.enable = true;
+        userDirs = {
+          enable = true;
+          createDirectories = false;
+          desktop = null;
+          documents = null;
+          download = null;
+          music = null;
+          pictures = null;
+          publicShare = null;
+          templates = null;
+          videos = null;
+        };
+      };
+      home = {
+        file = {
+          "ssh" = {
+            source = config.lib.file.mkOutOfStoreSymlink "${inputs.zeroq.dirs.storage}/SSH/${inputs.zeroq.devices.server.hostname}";
+            target = ".ssh";
+          };
+        };
+        username = "${inputs.zeroq.devices.admin}";
+      };
+
+    };
+  nixosModule =
+    { ... }:
+    {
+      home-manager = {
+        useGlobalPkgs = true;
+        useUserPackages = true;
+        users.${inputs.zeroq.devices.admin} = homeModule;
+      };
+    };
+in
+(
+  (inputs.home-manager.lib.homeManagerConfiguration {
+    modules = [
+      homeModule
+    ];
+    pkgs = inputs.nixpkgs.legacyPackages.x86_64-linux;
+  })
+  // {
+    inherit nixosModule;
+  }
+)